%{
#include "cmd.h"
#include "lex.yy.c"
#include <stdio.h>

%}

%union {
    char *str;
    struct Command *cmd;
    CommandType cmdType;
    int fd;
}

%token <str> WORD STRING error FD_REDIRECT
%token NEWLINE PIPE AND OR REDIRECT_IN REDIRECT_OUT BACKGROUND LPAREN RPAREN APPEND

%type <cmd> line command part runcommand
%type <cmdType> separator

%locations
%nonassoc WORD
%nonassoc BACKGROUND
%nonassoc REDIRECT_IN REDIRECT_OUT

%%

line:
    runcommand line { /* empty */ }
    | /* empty */ { $$ = NULL; }
    ;

runcommand:
    command NEWLINE {
        $$ = $1;
        runCmd($$);
        showPrompt();
    }
    | NEWLINE {
        $$ = NULL;
        showPrompt();
    }
    ;

command:
    part {
        $$ = $1;
    }
    | part separator command {
        $$ = newCmd();
        $$->type = $2;
        $$->left = $1;
        $$->right = $3;
    }
    | LPAREN command RPAREN {
        $$ = $2;
    } 
    ;

separator:
    PIPE { $$ = CMD_PIPE; }
    | AND { $$ = CMD_AND; }
    | OR { $$ = CMD_OR; }
    ;

part:
    part WORD {
        $$ = $1;
        argInsert($$, $2, false);
    }
    | WORD {
        $$ = newCmd();
        argInsert($$, $1, false);
    }
    | part STRING {
        $$ = $1;
        argInsert($$, $2, true);
    }
    | STRING {
        $$ = newCmd();
        argInsert($$, $1, true);
    }
    | part REDIRECT_IN WORD {
        $$ = $1;
        $$->redirectFile[0] = $3;
    }
    | part REDIRECT_OUT WORD {
        $$ = $1;
        $$->redirectFile[1] = $3;
    }
    | part APPEND WORD {
        $$ = $1;
        $$->redirectFile[1] = $3;
        $$->redirectFD[1] = -1;
    }
    | part FD_REDIRECT {
        $$ = $1;
        $$->redirectFD[$2[0] - '0'] = $2[3] - '0';
    }
    | part BACKGROUND {
        $$ = $1;
        $$->background = true;
    }
    ;

%%